rename modules to configs

configs/common.nix

@@ -0,0 +1,120 @@
+{
+  lib,
+  pkgs,
+  config,
+  nixpkgs,
+  agenix,
+  ...
+}: {
+  age = {
+    identityPaths = ["/etc/age/key"];
+
+    secrets = {
+      rootPassword.file = ../secrets/${config.networking.hostName}/rootPassword.age;
+      userPassword.file = ../secrets/userPassword.age;
+      tailscaleKey.file = ../secrets/tailscaleKey.age;
+    };
+  };
+
+  boot = {
+    kernelPackages = pkgs.linuxPackages_latest;
+    kernelParams = ["quiet" "loglevel=3"];
+  };
+
+  console.keyMap = "fr";
+
+  environment = {
+    systemPackages = with pkgs; let
+      inherit (pkgs.stdenv.hostPlatform) system;
+    in [
+      agenix.packages.${system}.default
+      neovim
+      git
+      curl
+    ];
+
+    variables = {
+      EDITOR = lib.getExe pkgs.neovim;
+    };
+  };
+
+  home-manager = {
+    useGlobalPkgs = true;
+    useUserPackages = true;
+  };
+
+  i18n.defaultLocale = "en_US.UTF-8";
+
+  networking.networkmanager.enable = true;
+
+  nix = {
+    gc = {
+      automatic = true;
+      dates = "weekly";
+      options = "-d";
+    };
+
+    registry = let
+      nixpkgsRegistry.flake = nixpkgs;
+    in {
+      nixpkgs = nixpkgsRegistry;
+      n = nixpkgsRegistry;
+    };
+
+    settings = {
+      auto-optimise-store = true;
+      experimental-features = ["nix-command" "flakes"];
+      trusted-users = ["root" "@wheel"];
+    };
+  };
+
+  nixpkgs = {
+    config.allowUnfree = true;
+    overlays = [(import ../exprs/overlay.nix)];
+  };
+
+  programs = {
+    ssh.startAgent = true;
+
+    direnv.enable = true;
+
+    command-not-found.enable = false;
+    nix-index = {
+      enable = true;
+      enableFishIntegration = true;
+    };
+  };
+
+  security = {
+    rtkit.enable = true;
+    polkit.enable = true;
+  };
+
+  services = {
+    openssh = {
+      enable = true;
+      openFirewall = lib.mkDefault false;
+    };
+
+    vscode-server.enable = true;
+
+    tailscale = {
+      enable = true;
+      useRoutingFeatures = "both";
+      extraUpFlags = ["--ssh"];
+      authKeyFile = config.age.secrets.tailscaleKey.path;
+    };
+  };
+
+  time.timeZone = "Europe/Paris";
+
+  users.users.root.hashedPasswordFile = config.age.secrets.rootPassword.path;
+
+  # This value determines the NixOS release from which the default
+  # settings for stateful data, like file locations and database versions
+  # on your system were taken. It‘s perfectly fine and recommended to leave
+  # this value at the release version of the first install of this system.
+  # Before changing this value read the documentation for this option
+  # (e.g. man configuration.nix or on https://nixos.org/nixos/options.html).
+  system.stateVersion = lib.mkDefault "23.11"; # Did you read the comment?
+}

configs/desktop.nix

@@ -0,0 +1,192 @@
+{
+  lib,
+  pkgs,
+  config,
+  catppuccin,
+  ...
+}: let
+  username = "leo";
+in {
+  imports = [
+    ../programs
+    (lib.mkAliasOptionModule ["hm"] ["home-manager" "users" username])
+  ];
+
+  boot = {
+    extraModulePackages = with config.boot.kernelPackages; [v4l2loopback];
+    kernelModules = ["v4l2loopback"];
+
+    loader = {
+      systemd-boot.enable = lib.mkForce false;
+      efi.canTouchEfiVariables = true;
+    };
+
+    lanzaboote = {
+      enable = true;
+      pkiBundle = "/etc/secureboot";
+    };
+  };
+
+  environment.systemPackages = with pkgs; [sbctl];
+
+  fonts = {
+    packages = with pkgs; [
+      iosevka
+      jetbrains-mono
+      cantarell-fonts
+      twitter-color-emoji
+      (nerdfonts.override {fonts = ["Iosevka" "JetBrainsMono"];})
+    ];
+
+    fontconfig.defaultFonts = {
+      emoji = ["Twitter Color Emoji"];
+    };
+  };
+
+  hardware = {
+    opengl.enable = true;
+    pulseaudio.enable = false;
+
+    xone.enable = true;
+    xpadneo.enable = true;
+  };
+
+  hm = {
+    imports = [
+      catppuccin.homeManagerModules.catppuccin
+    ];
+
+    home = {
+      packages = with pkgs; [
+        font-manager
+        gimp
+        gnome.gnome-calculator
+        jetbrains.idea-ultimate
+        libreoffice-fresh
+        mate.eom
+        mold
+        mpv
+        nwg-look
+        obs-studio
+        obsidian
+        osu-lazer-bin
+        pavucontrol
+        polkit_gnome
+        prismlauncher
+        sccache
+        shotcut
+        (vesktop.override {withSystemVencord = false;})
+        wine-discord-ipc-bridge
+      ];
+
+      stateVersion = "23.11";
+    };
+
+    services = {
+      gpg-agent = {
+        enable = true;
+        pinentryFlavor = "gnome3";
+      };
+    };
+
+    gtk = {
+      enable = true;
+      catppuccin = {
+        enable = true;
+        flavour = "macchiato";
+        accent = "sky";
+      };
+    };
+  };
+
+  i18n.extraLocaleSettings = {
+    LC_ADDRESS = "fr_FR.UTF-8";
+    LC_IDENTIFICATION = "fr_FR.UTF-8";
+    LC_MEASUREMENT = "fr_FR.UTF-8";
+    LC_MONETARY = "fr_FR.UTF-8";
+    LC_NAME = "fr_FR.UTF-8";
+    LC_NUMERIC = "fr_FR.UTF-8";
+    LC_PAPER = "fr_FR.UTF-8";
+    LC_TELEPHONE = "fr_FR.UTF-8";
+    LC_TIME = "fr_FR.UTF-8";
+  };
+
+  programs = {
+    gnupg.agent = {
+      enable = true;
+      pinentryFlavor = "gnome3";
+    };
+
+    firefox = {
+      enable = true;
+      package = pkgs.librewolf;
+    };
+
+    seahorse.enable = true;
+    file-roller.enable = true;
+
+    steam.enable = true;
+
+    thunar = {
+      enable = true;
+      plugins = with pkgs.xfce; [thunar-volman thunar-archive-plugin];
+    };
+
+    virt-manager.enable = true;
+  };
+
+  security.pam.services.login.enableGnomeKeyring = true;
+
+  services = {
+    # apparently needed for mesa
+    xserver = {
+      enable = true;
+      xkb.layout = "fr";
+      displayManager = {
+        lightdm.enable = false;
+        gdm = {
+          enable = true;
+          wayland = true;
+        };
+        defaultSession = "hyprland";
+      };
+    };
+
+    printing.enable = true;
+
+    pipewire = {
+      enable = true;
+      alsa.enable = true;
+      alsa.support32Bit = true;
+      pulse.enable = true;
+      wireplumber.enable = true;
+    };
+
+    ratbagd.enable = true;
+    udisks2.enable = true;
+    gvfs.enable = true;
+    tumbler.enable = true;
+    gnome.gnome-keyring.enable = true;
+  };
+
+  sound.enable = true;
+
+  users.users."${username}" = {
+    isNormalUser = true;
+    shell = pkgs.fish;
+    extraGroups = ["networkmanager" "wheel" "video" "libvirtd"];
+    hashedPasswordFile = config.age.secrets.userPassword.path;
+  };
+
+  virtualisation.libvirtd.enable = true;
+
+  xdg = {
+    portal = {
+      enable = true;
+      extraPortals = with pkgs; [xdg-desktop-portal-gtk];
+    };
+
+    mime.enable = true;
+    icons.enable = true;
+  };
+}

configs/server.nix

@@ -0,0 +1,30 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}: let
+  username = "uku";
+in {
+  imports = [
+    (lib.mkAliasOptionModule ["hm"] ["home-manager" "users" username])
+
+    ../programs/fish.nix
+    ../programs/git.nix
+    ../programs/starship.nix
+  ];
+
+  hm.home.stateVersion = "23.11";
+
+  services.tailscale.extraUpFlags = ["--advertise-exit-node"];
+
+  users.users."${username}" = {
+    isNormalUser = true;
+    shell = pkgs.fish;
+    extraGroups = ["networkmanager" "wheel"];
+    hashedPasswordFile = config.age.secrets.userPassword.path;
+    openssh.authorizedKeys.keys = [
+      "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIN+7+KfdOrhcnHayxvOENUeMx8rE4XEIV/AxMHiaNUP8"
+    ];
+  };
+}