add expressions and nixpkgs overlay
This commit is contained in:
parent
8287258ec0
commit
370aaa9c5a
4 changed files with 187 additions and 0 deletions
3
exprs/overlay.nix
Normal file
3
exprs/overlay.nix
Normal file
|
@ -0,0 +1,3 @@
|
|||
final: prev: {
|
||||
vesktop = final.callPackage ./vesktop.nix {};
|
||||
}
|
13
exprs/use_system_vencord.patch
Normal file
13
exprs/use_system_vencord.patch
Normal file
|
@ -0,0 +1,13 @@
|
|||
diff --git a/src/main/constants.ts b/src/main/constants.ts
|
||||
index d5c5fa6..a1b32f1 100644
|
||||
--- a/src/main/constants.ts
|
||||
+++ b/src/main/constants.ts
|
||||
@@ -16,7 +16,7 @@ export const VENCORD_THEMES_DIR = join(DATA_DIR, "themes");
|
||||
// needs to be inline require because of circular dependency
|
||||
// as otherwise "DATA_DIR" (which is used by ./settings) will be uninitialised
|
||||
export const VENCORD_FILES_DIR =
|
||||
- (require("./settings") as typeof import("./settings")).Settings.store.vencordDir || join(DATA_DIR, "vencordDist");
|
||||
+ (require("./settings") as typeof import("./settings")).Settings.store.vencordDir || "@vencord@";
|
||||
|
||||
export const USER_AGENT = `Vesktop/${app.getVersion()} (https://github.com/Vencord/Vesktop)`;
|
||||
|
169
exprs/vesktop.nix
Normal file
169
exprs/vesktop.nix
Normal file
|
@ -0,0 +1,169 @@
|
|||
{
|
||||
lib,
|
||||
stdenv,
|
||||
stdenvNoCC,
|
||||
gcc13Stdenv,
|
||||
fetchFromGitHub,
|
||||
substituteAll,
|
||||
makeWrapper,
|
||||
makeDesktopItem,
|
||||
copyDesktopItems,
|
||||
vencord,
|
||||
electron,
|
||||
pipewire,
|
||||
libpulseaudio,
|
||||
libicns,
|
||||
jq,
|
||||
moreutils,
|
||||
cacert,
|
||||
nodePackages,
|
||||
}:
|
||||
stdenv.mkDerivation (finalAttrs: {
|
||||
pname = "vesktop";
|
||||
version = "0.4.3";
|
||||
|
||||
src = fetchFromGitHub {
|
||||
owner = "Vencord";
|
||||
repo = "Vesktop";
|
||||
rev = "v${finalAttrs.version}";
|
||||
hash = "sha256-wGOyDGY0FpAVS5+MTiKrOpDyd13ng0RLGAENW5tXuR4=";
|
||||
};
|
||||
|
||||
# NOTE: This requires pnpm 8.10.0 or newer
|
||||
# https://github.com/pnpm/pnpm/pull/7214
|
||||
pnpmDeps = assert lib.versionAtLeast nodePackages.pnpm.version "8.10.0";
|
||||
stdenvNoCC.mkDerivation {
|
||||
pname = "${finalAttrs.pname}-pnpm-deps";
|
||||
inherit (finalAttrs) src version patches ELECTRON_SKIP_BINARY_DOWNLOAD;
|
||||
|
||||
nativeBuildInputs = [
|
||||
jq
|
||||
moreutils
|
||||
nodePackages.pnpm
|
||||
cacert
|
||||
];
|
||||
|
||||
pnpmPatch = builtins.toJSON {
|
||||
pnpm.supportedArchitectures = {
|
||||
os = ["linux"];
|
||||
cpu = ["x64" "arm64"];
|
||||
};
|
||||
};
|
||||
|
||||
postPatch = ''
|
||||
mv package.json package.json.orig
|
||||
jq --raw-output ". * $pnpmPatch" package.json.orig > package.json
|
||||
'';
|
||||
|
||||
# https://github.com/NixOS/nixpkgs/blob/763e59ffedb5c25774387bf99bc725df5df82d10/pkgs/applications/misc/pot/default.nix#L56
|
||||
installPhase = ''
|
||||
export HOME=$(mktemp -d)
|
||||
|
||||
pnpm config set store-dir $out
|
||||
pnpm install --frozen-lockfile --ignore-script
|
||||
|
||||
rm -rf $out/v3/tmp
|
||||
for f in $(find $out -name "*.json"); do
|
||||
sed -i -E -e 's/"checkedAt":[0-9]+,//g' $f
|
||||
jq --sort-keys . $f | sponge $f
|
||||
done
|
||||
'';
|
||||
|
||||
dontBuild = true;
|
||||
dontFixup = true;
|
||||
outputHashMode = "recursive";
|
||||
outputHash = "sha256-nNXe0vSQiQTkiRqgScKlpkpG/BJc2eIY2ueAd9sk36c=";
|
||||
};
|
||||
|
||||
nativeBuildInputs = [
|
||||
copyDesktopItems
|
||||
nodePackages.pnpm
|
||||
nodePackages.nodejs
|
||||
makeWrapper
|
||||
];
|
||||
|
||||
patches = [
|
||||
(substituteAll {
|
||||
inherit vencord;
|
||||
src = ./use_system_vencord.patch;
|
||||
})
|
||||
];
|
||||
|
||||
ELECTRON_SKIP_BINARY_DOWNLOAD = 1;
|
||||
|
||||
preBuild = ''
|
||||
export HOME=$(mktemp -d)
|
||||
export STORE_PATH=$(mktemp -d)
|
||||
|
||||
cp -Tr "$pnpmDeps" "$STORE_PATH"
|
||||
chmod -R +w "$STORE_PATH"
|
||||
|
||||
pnpm config set store-dir "$STORE_PATH"
|
||||
pnpm install --offline --frozen-lockfile --ignore-script
|
||||
patchShebangs node_modules/{*,.*}
|
||||
'';
|
||||
|
||||
postBuild = ''
|
||||
pnpm build
|
||||
# using `pnpm exec` here apparently makes it ignore ELECTRON_SKIP_BINARY_DOWNLOAD
|
||||
./node_modules/.bin/electron-builder \
|
||||
--dir \
|
||||
-c.electronDist=${electron}/libexec/electron \
|
||||
-c.electronVersion=${electron.version}
|
||||
'';
|
||||
|
||||
# this is consistent with other nixpkgs electron packages and upstream, as far as I am aware
|
||||
# yes, upstream really packages it as "vesktop" but uses "vencorddesktop" file names
|
||||
installPhase = let
|
||||
# this is mainly required for venmic
|
||||
libPath = lib.makeLibraryPath [
|
||||
libpulseaudio
|
||||
pipewire
|
||||
gcc13Stdenv.cc.cc.lib
|
||||
];
|
||||
in ''
|
||||
runHook preInstall
|
||||
|
||||
mkdir -p $out/opt/Vesktop/resources
|
||||
cp dist/linux-*unpacked/resources/app.asar $out/opt/Vesktop/resources
|
||||
|
||||
pushd build
|
||||
${libicns}/bin/icns2png -x icon.icns
|
||||
for file in icon_*x32.png; do
|
||||
file_suffix=''${file//icon_}
|
||||
install -Dm0644 $file $out/share/icons/hicolor/''${file_suffix//x32.png}/apps/vencorddesktop.png
|
||||
done
|
||||
|
||||
makeWrapper ${electron}/bin/electron $out/bin/vencorddesktop \
|
||||
--prefix LD_LIBRARY_PATH : ${libPath} \
|
||||
--add-flags $out/opt/Vesktop/resources/app.asar \
|
||||
--add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations}}"
|
||||
|
||||
runHook postInstall
|
||||
'';
|
||||
|
||||
desktopItems = [
|
||||
(makeDesktopItem {
|
||||
name = "vencorddesktop";
|
||||
desktopName = "Vesktop";
|
||||
exec = "vencorddesktop %U";
|
||||
icon = "vencorddesktop";
|
||||
startupWMClass = "VencordDesktop";
|
||||
genericName = "Internet Messenger";
|
||||
keywords = ["discord" "vencord" "electron" "chat"];
|
||||
})
|
||||
];
|
||||
|
||||
passthru = {
|
||||
inherit (finalAttrs) pnpmDeps;
|
||||
};
|
||||
|
||||
meta = with lib; {
|
||||
description = "An alternate client for Discord with Vencord built-in";
|
||||
homepage = "https://github.com/Vencord/Vesktop";
|
||||
license = licenses.gpl3Only;
|
||||
maintainers = with maintainers; [getchoo Scrumplex vgskye pluiedev];
|
||||
platforms = ["x86_64-linux" "aarch64-linux"];
|
||||
mainProgram = "vencorddesktop";
|
||||
};
|
||||
})
|
|
@ -163,6 +163,8 @@ in {
|
|||
};
|
||||
};
|
||||
|
||||
nixpkgs.overlays = [(import ../exprs/overlay.nix)];
|
||||
|
||||
programs = {
|
||||
gnupg.agent = {
|
||||
enable = true;
|
||||
|
|
Loading…
Reference in a new issue